WshEnvironmentオブジェクト

[概要]

環境変数の値を格納しているオブジェクトです。

[機能を提供するファイル]

wshom.ocx
Windows Scripting Host Runtime Library

[呼び出し方]

Set WshShell=Wscript.CreateObject("Wscript.Shell")
Set WshEnv=WSHShell.Environment
など。実際には、Environmentプロパティに"SYSTEM"、"USER"、"VOLATILE"、"PROCESS"という引数を指定可。（詳しくは、WshShellオブジェクト参照。）

[主なメソッド]

• Remove strName
  　strNameで指定した環境変数を削除します（WinNT/2000のみ）。
  　削除できる環境変数は、「ユーザー環境変数（USER)」・「システム環境変数（SYSTEM、Administratorアカウントのみ）」「揮発性環境変数(VOLATILE)」です。
  　存在しない環境変数名を指定すると、エラーが発生します。
  (例）:

  Set WshShell = WScript.CreateObject("WScript.Shell")
  Set WshEnv = WshShell.Environment("USER")
  WshEnv("test")="hoge" '"test"という環境変数に、"hoge"という値をセット
  MsgBox "環境変数testを定義しました。"
  WshEnv.Remove "test" '"test"という環境変数を削除
  MsgBox "環境変数testを削除しました。"

[主なプロパティ]

• Count
  　環境変数の総数を返します。
  
  
• Length
  　Countプロパティと同じ値を返します。
  
  
• Item(strName)
  　strNameに対応する環境変数の値を取得します。値の設定も可（WinNT/2000のみ）。
  　値を設定できるのは、「ユーザー環境変数（USER)」・「システム環境変数（SYSTEM、Administratorアカウントのみ）」「揮発性環境変数(VOLATILE)」です。
  　strNameには、環境変数名が指定できます。
  (例）:

  Dim WSHShell,WSHEnv,strList,strEnv
  Set WSHShell = WScript.CreateObject("WScript.Shell")
  Set WSHEnv = WshShell.Environment("PROCESS") '1.WshEnvironmentオブジェクトを作成
  MsgBox "Windowsインストールフォルダは、" & WSHEnv.Item("windir") & "です。" 
  '2.Windowsがインストールされているフォルダ名を表示
  MsgBox "環境変数の総数は、" & WSHEnv.Count & "です。"
  '3.環境変数の総数を表示
  strList="環境変数一覧は以下の通りです。" & vbCrLf
  For Each strEnv In WSHEnv
  '4.すべての環境変数を列挙
  	strList=strList & strEnv & vbCrLf
  Next
  MsgBox strList

[関連オブジェクト]

• WshShellオブジェクト

[UP]