WshShell

WshShellオブジェクト (Wscript.Shell)

[概要]

　WSHが提供する、便利な機能を呼び出すためのオブジェクトです。

[機能を提供するファイル]

wshom.ocx
Windows Scripting Host Runtime Library

[呼び出し方]

Set WSHShell=Wscript.CreateObject("Wscript.Shell")

[主なメソッド]

AppActivate (strTitle)
　[WSH2.0以上]　任意のウィンドウをアクティブにするメソッドです。引数strTitleには、ウィンドウのタイトルを指定します。
　strTitleに前方/後方一致するタイトルを持つウィンドウがあれば、それをアクティブにし、Trueを返します。見つからなかった場合はFalseを返します。

　(例) :
```
'「AppTitle」というタイトルを持つウィンドウが表示されるまで待つ。
Dim ret
Set WshShell = WScript.CreateObject("WScript.Shell")
Do While ret=False
	ret=WshShell.AppActivate("AppTitle")
	wscript.sleep 100
Loop
```
ExpandEnvironmentStrings (strString)
　DOSプロンプトの環境変数の値を返します。環境変数は、DOSプロンプトでsetコマンドを実行するとわかります。strStringは%環境変数名%のように指定します。
　すべての環境変数を取得したい場合は、WshEnviromentオブジェクトを使う方がよいでしょう。
　(例) :
```
Set WSHShell=Wscript.CreateObject("Wscript.Shell")
MsgBox WSHShell.ExpandEnvironmentStrings("%winbootdir%")
'Windowsがインストールされているフォルダを表示。
```
Popup (strText, [intSecondsToWait], [strTitle], [intType])
　strTextに指定した文字列をメッセージボックスで表示させます。
　intSecondToWaitに1以上の整数を指定すると、指定した秒数が経過するとメッセージボックスが自動的に閉じられます。
　strTitleにはメッセージボックスのタイトルを指定します。省略すると、「Windows スクリプティングホスト」になります。
　intTypeにはメッセージボックスのスタイルを指定します。 intTypeは、VBSのMsgBox関数と同じ引数を指定できます。詳しくはVBSランゲージリファレンスを見てください。
　他に、7という値を指定することができ、ボタンのないダイアログを表示することも可能です。その場合は必ず、intSecondToWaitに1以上の値を指定してください。
　また、Popupメソッドは、ユーザーが押したボタンの種類を返します。返す値についてもMsgBox関数と同様ですが、intSecondToWaitの時間を経過して自動的にメッセージボックスが閉じられた場合は、-1という値が返ります。
　(例) :
```
Set WSHShell=Wscript.CreateObject("Wscript.Shell")
intMsg=WSHShell.Popup ("このダイアログは5秒後自動的に閉じます。",5,"Test",vbOKOnly)
If intMsg=-1 Then MsgBox "自動的に閉じました。このダイアログは自動的に閉じません(^^;",vbOKOnly,"Test"
```

RegWrite strName, anyValue, [strType]
　レジストリにキーや値を書き込みます。
　strNameには値の名前、もしくはキー(最後を\にするとキーと見なされる)を指定します。
　なお、キーや値の名前を指定するときは、下の表に従って短い名前を指定する必要があります。これは以下のRegDelete,RegReadメソッドでも同様です。

HKEY_CLASSES_ROOT HKEY_USERS HKEY_CURRENT_CONFIG	HKCR
HKEY_CURRENT_USER	HKCU
HKEY_LOCAL_MACHINE	HKLM

　anyValueには任意の値を指定します。　
　strTypeには、値の種類を指定できます。REG_SZ, REG_EXPAND_SZ (どちらも文字列。違い不明) REG_DWORD (DWORD値) REG_BINARY (バイナリ)を指定できます。
　省略すると、文字列の値が書き込まれます。

　REG_DWORDを指定すると、anyValueの値に文字列型の値を指定しても、自動的に整数値に変換され書き込まれますが、REG_BINARYでは整数値しか指定できません。

　バイナリ型のデータで、たとえば値がf5,18,0c,1eなら&H1E0C18F5(もしくは504109301)のように指定します。
　１(=&H01)などの1バイトの値をそのまま書き込もうとすると、01 00のように2バイトになってしまいます。これを回避するには、CByte(&H01)のように、明示的にバイト型に変換した値を指定します。
　ただし、REG_BINARYはLong型の整数しか指定できないため、書き込める値に限度(すなわち&HFFFFFFFFまで)があります。これを越えるデータを指定したい場合は、.regファイルを自前で用意し、
WshShell.Run "regedit /s hogehoge.reg"
のように/sオプションをつけて実行し、レジストリに書き込んでください。（/sオプションをつけると、確認メッセージが出なくなります）

　(例) :

'登録情報変更スクリプト。これってけっこう便利。
Set WSHShell=Wscript.CreateObject("Wscript.Shell")
Call RegChange ("HKLM\Software\Microsoft\Windows\CurrentVersion\RegisteredOwner","ユーザー名を入力してください")
Call RegChange ("HKLM\Software\Microsoft\Windows\CurrentVersion\RegisteredOrganization","会社名を入力してください")

Sub RegChange(strName,strMsg)
	Dim Value
	Value=InputBox (strMsg,"登録変更",WSHShell.RegRead (strName))
	If Value<>"" Then
		WSHShell.RegWrite strName,Value,"REG_SZ"
	End If
End Sub

RegDelete strName
　レジストリからキーや値を削除します。
　strNameが存在しないキー・値の名前の場合は、実行時エラーが発生します。
strName以下にサブキーが存在する場合、エラーが発生します。(Win2000のみ)
strNameには値の名前、もしくはキー(最後を\にするとキーと見なされる)を指定します。
　(例) :
```
'ファイル検索の履歴削除
On Error Resume Next
Dim WSHShell
Set WSHShell = WScript.CreateObject("WScript.Shell")
Const Key="HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Doc Find Spec MRU\"
WSHShell.RegDelete Key
```
RegRead (strName)
　レジストリのキーや値を読みます。
　strNameには値の名前、もしくはキー(最後を\にするとキーと見なされる)を指定します。
　strNameが存在しないキー・値の名前の場合は、実行時エラーが発生します。
　strNameに対応する値を返します。REG_DWORDやREG_BINARYの値は、整数値のバイト型データ(0から256)の一次元配列で返します。
　(例) :
```
'REG_BINARYの値を読む例
Set WSHShell=Wscript.CreateObject("Wscript.Shell")
arr=WSHShell.RegRead ("HKLM\Software\Microsoft\Windows\CurrentVersion\DigitalProductId")
a=arr
b=arr
For I = LBound(arr) To UBound(arr)
	a(I) = CInt(arr(I))
	b(I) = Hex (CInt(arr(I)))
Next
msgbox Join(a),,"10進"
msgbox Join(b),,"16進"
```
　なお、あるキー以下にどんなサブキーや値があるかを直接確認することはできません。その場合は、WshShell.Run "regedit /e C:\Windows\Temp\shellfol.reg HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"のようにして、テキストファイル化し、それを読み取ってやるなどの措置が必要になります。
Run (strCommand, [intWindowStyle], [blnWaitOnReturn])
　アプリケーションまたはファイルを開きます。
　strCommandにはアプリまたはファイルのパス(オプション含む)を指定します。パスの通っているディレクトリにあるファイルは、ファイル名を指定するだけでOKです。
　パスは " またはChr(34)でくくって指定してください。ただし半角スペースが含まれないパスの場合は省略できます。
　ファイルを指定した場合、関連づけに従ってアプリが当該ファイルを読み込んだ状態で起動します。
　intWindowStyleには、ウィンドウサイズを表す整数値を指定できます。省略時は1(通常サイズ)です。その他の値を指定すると、1とみなされます。他の値については、このページの下の方にある、WshWindowStyleの定数が指定できます。
　blnWaitOnReturnにTrueを指定すると、アプリの実行が終了するまで次のステップを実行しなくなり、Falseを指定すると、アプリを実行したと同時に次のステップへ制御を移すようになります。省略時はFalseです。
　blnWaitOnReturnがFalseのとき、アプリが正常実行された場合、Runメソッドは0を返します。
　　(例) :
```
Set WSHShell=Wscript.CreateObject("Wscript.Shell")
MsgBox "メモ帳を起動します。"
WSHShell.Run "notepad.exe",1,True
MsgBox "Tips.txtを最大化で表示します。"
WSHShell.Run "tips.txt",3,True
MsgBox "Dirの結果をc:\filelist.txtに出力します。"
WSHShell.Run "command.com /c dir>c:\filelist.txt",0
MsgBox "IEを起動します。"
WSHShell.Run Chr(34) & "C:\Program Files\Internet Explorer\IEXPLORE.EXE" & Chr(34) ,1
```

SendKeys str
　[WSH2.0以上]　アクティブウィンドウに任意のキーコードを送るメソッドです。AppActivateメソッドと併用します。引数strには、キーコードを表す文字列を指定します。詳しくはヘルプをどうぞ。
(例):

'このスクリプトは、Outlook Express4を立ち上げ、「すべてダウンロード」を実行するスクリプトです。
'・ウィンドウタイトルに "Express"が含まれていること。また他に該当するウィンドウが表示されていないこと
'・起動時にダイヤルしない設定にしていること
'が条件です。(レジストリの設定を読み込むことでここら辺は調整可能ですが、本筋とはなれるのでここでは省略しました)
'ダウンロード後に切断するかどうかの設定はお好みで。
'キーコードを送るタイミングその他で、うまく動作しない可能性もあります。ご了承ください。
'また、OE5での動作は想定していません。

Set WSHShell = WScript.CreateObject("WScript.Shell")
WSHShell.Run "C:\Progra~1\Outloo~1\msimn.exe" 'OEを立ち上げる。
WScript.Sleep 5000 '5秒ウェイトを入れ起動を待つ。適宜調整してください。
WSHShell.AppActivate "Express" 'タイトルが"Express"で終わるウィンドウを探し、それを前面に表示させる。
WScript.Sleep 100
WSHShell.SendKeys "^+M" 'Ctrl+Shift+MのキーコードをOutlook Expressのウィンドウに送る。「すべてダウンロード」のショートカットキーです。
WScript.Sleep 100
WSHShell.SendKeys "%Y" 'Alt+Yのキーコードを送る。オンラインに切り替えますか?というダイアログで「はい」を押す操作です。

ConnectObject objObject, strPrefix
　[WSH2.0以上] CreateObjectメソッドにより作成されたオブジェクトに接続し、イベントを宣言します。引数objObjectは、CreateObjectメソッドで作成されたオブジェクトを指定し、strPrefixにイベントにつけるプレフィックス(接頭語)を指定します。
　CreateObjectメソッドの第二引数でプレフィックスを指定するのと同様と思われます。
　下の例は、架空のProgID(nantoka.kantoka)を持つオブジェクトの場合です。
(例):
```
Set X =WScript.CreateObject("nantoka.kantoka") 'オブジェクト作成
X.nantokamethod 'メソッドの実行
WScript.ConnectObject(X,"Event") 'イベントの宣言

Sub Event_nantokaevent(strNantoka) 'イベント
	msgbox strNantoka
End Sub
```
LogEvent intType,strMessage,[strTarget]
　[WSH2.0以上] WSHでの実行ログをログファイルに記録するメソッドです。このメソッドを実行すると、Windowsフォルダのwsh.logファイルに、時刻と、引数として指定したログのタイプと、テキストが追記されます。NTの場合は、NTのイベントログに記録されるそうです。
　いちいちTextStreamオブジェクトを使わなくてもログが取れるというメリットがあります。
　ログのタイプ等についてはヘルプをご覧ください。
　以下は、スクリプトにエラー記録ルーチンを組み込む参考例です。
(例):
```
On Error Resume Next
Set WSHShell = WScript.CreateObject("WScript.Shell")

...処理...

If Err.Number<>0 Then
	'エラーが発生した場合は、"Error"タイプを指定し、エラー情報を書き込む。
	WSHShell.LogEvent 1,Err.Source & "/" & Err.Number & "/" & Err.Description
Else
	'エラーが発生しなかった場合は、"Success"タイプを指定し、そのスクリプト名を書き込む。
	WSHShell.LogEvent 0,WScript.ScriptFullName
End If
```
CreateShortcut(strPathname)
　WshShortCutオブジェクトまたはWshUrlShortcutオブジェクトを返します。
　strPathnameには、ショートカットのパス(*.lnk か *.url) を指定します。これらのファイル名は存在しないファイル名でも構いません。なお、ほかの拡張子を指定するとエラーが発生します。

[主なプロパティ]

SpecialFolders
　WshSpecialFoldersオブジェクトを返します。
Environment([strType])
　WshEnvironmentオブジェクト（環境変数を格納したオブジェクト）を返します。
　Windows95/98では、strTypeには、"PROCESS"(プロセス環境変数；すべての環境変数）が指定できます。strTypeを省略することもできます。（その場合はもちろん"PROCESS"になります）

　WindowsNT4.0/2000では、strTypeには、

"SYSTEM"(システム環境変数；すべてのユーザーに適用されるHKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Session Manager\Environment）
"USER"(ユーザー環境変数；ユーザーごとに設定可能HKEY_CURRENT_USER\Environment）
"VOLATILE"(揮発性環境変数；ログオフとともにクリアされるHKEY_CURRENT_USER\Volatile Environment）
"PROCESS"(プロセス環境変数；現在読み込まれているすべての環境変数。読み込み専用）

が指定できます。strType省略時は、"SYSTEM"になります。ただし、Administratorアカウントを持つユーザー以外は、strTypeに"SYSTEM"を指定、もしくは省略するとエラーになります。

　Win9x、NT（Administratorもしくはほかのユーザー）の区別なく、すべての場合でエラーが発生しないようにするには、strTypeに"PROCESS"を指定するとよいでしょう。

[定数]

●WshWindowStyle

定数名と値	意味
Const WshHide = 0	非表示
Const WshNormalFocus = 1	通常サイズ
Const WshMinimizedFocus = 2	最小化
Const WshMaximizedFocus = 3	最大化
Const WshNormalNoFocus = 4	通常サイズかつ非フォーカス
Const WshMinimizedNoFocus = 6	最小化かつ非フォーカス

[関連オブジェクト]

[UP]